; Oytun Cleus'un
; Süper Fantastik Burç Yorumcusu
;
; Bu kod yığını, 27 Nisan 2008'de
; Oytun Cleus tarafından, BLaCK_and_WHiTe için
; hazırlanmıştır.
;
; Bu satırlar kullanılarak,
; Creative Commons BY-NC-SA lisans türüne
; uygun olarak kullanılabilir.


dialog burc {
  title "Süper Fantastik Burç Yorumcusu"
  size -1 -1 216 155
  option dbu
  box "Burcunuz", 1, 2 2 75 133
  list 2, 4 9 71 124, size
  box "Yorumu", 3, 76 2 138 133
  edit "", 4, 78 9 134 124, read multi autovs
  button "Kapat", 5, 176 140 37 12, ok
  box "", 6, -1 133 228 50
  text "", 7, 3 142 167 8
}

on 1:dialog:burc:init:*: {
  burc | did -ra $dname 7 Burç durumu güncelleniyor...
}
on 1:dialog:burc:sclick:2: {
  did -ra $dname 4 $readini(burctemp.txt,$did(2).seltext,acikla)
}
on 1:dialog:burc:close:0: {
  .sockclose burc | .timerBurcOku off
}

alias burc {
  write -c burctemp.txt | set %burc.itemler h
  sockclose burc
  sockopen burc www.burclar.gen.tr 80
}
on 1:sockopen:burc: {
  if $sockerr > 1 { return }
  sockwrite -n $sockname GET /rss.asp HTTP/1.1
  sockwrite -n $sockname Host: www.burclar.gen.tr $+ $crlf $+ $crlf
  if !$dialog(burc) { dialog -m burc burc }
  did -ra burc 7 Bağlantı tamam, burçlar bekleniyor...
}
on 1:sockread:burc: {
  if $sockerr > 1 { return }
  .timerBurcOku 0 1 { did -ra burc 7 Bunu yapan: Oytun Cleus - 27 Nisan 2008 }
  sockread %t
  if <item> isin %t { set %burc.itemler e | return }
  if %burc.itemler == e {
    if !$dialog(burc) { dialog -m burc burc }
    did -ra burc 7 Burçlar indiriliyor...
    if *<title>*</title>* iswm %t {
      set %burc.badi $gettok($remove(%t,<title>,</title>,$chr(9)),1,32)
      did -a burc 2 $gettok($remove(%t,<title>,</title>,$chr(9)),1,32)
    }
    if *<description>*</description*> iswm %t {
      writeini burctemp.txt %burc.badi acikla $remove(%t,<description>,</description>,$chr(9))
    }
  }
}

menu query,status,channel {
  burc addonu: burc
}